function Jumper takes nothing returns nothing
     local timer t=GetExpiredTimer()
     local integer id=GetHandleId(t)
     local unit u=LoadUnitHandle(udg_h,id,1)
     local real L=LoadReal(udg_h,id,2)
     local integer i=LoadInteger(udg_h,id,3)+1
     local integer n=LoadInteger(udg_h,id,7)
     local real h=LoadReal(udg_h,id,4)
     local real MoveX=LoadReal(udg_h,id,5)
     local real MoveY=LoadReal(udg_h,id,6)
     local real A=MoveX*I2R(i)
     local real B=MoveY*I2R(i)
     local real x=SquareRoot(A*A+B*B)
     local real z
     local pathingtype pt=ConvertPathingType(LoadInteger(udg_h,id,8))
     local real bfh=LoadReal(udg_h,GetUnitTypeId(u),1)
     if i>n or GetWidgetLife(u)<=0. then
       if LoadInteger(udg_h,GetHandleId(u),2)==1 then
         call UnitAddType(u,UNIT_TYPE_GROUND)
         call UnitRemoveType(u,UNIT_TYPE_PEON)
         call SetUnitPathing(u,true)
         call UnitRemoveAbility(u,'B001')
         call SetUnitFlyHeight(u,bfh,0.)
         call UnitRemoveAbility(u,'B001')
       endif
       call FlushChildHashtable(udg_h,id)
       call DestroyTimer(t)
       call SaveInteger(udg_h,GetHandleId(u),2,LoadInteger(udg_h,GetHandleId(u),2)-1)
       set t=null
       set u=null
     else
       set z=4.*h*x/L*(1.-x/L)
       call SaveInteger(udg_h,id,3,i)
       if not IsTerrainPathable(GetUnitX(u)+MoveX,GetUnitY(u)+MoveY,pt) then
         call SetUnitX(u,GetUnitX(u)+MoveX)
         call SetUnitY(u,GetUnitY(u)+MoveY)
       endif
       call SetUnitFlyHeight(u,bfh+z+GetZ(GetUnitX(u),GetUnitY(u)),0.)
       set t=null
       set u=null
     endif
endfunction

function JumpContinue takes nothing returns nothing
     local timer t2=GetExpiredTimer()
     local integer id2=GetHandleId(t2)
     local unit u=LoadUnitHandle(udg_h,id2,1)
     local timer t=LoadTimerHandle(udg_h,id2,2)
     call DestroyTimer(t2)
     set t2=null
     call FlushChildHashtable(udg_h,id2)
     call UnitAddAbility(u,'Amrf')
     call UnitRemoveAbility(u,'Amrf')
     call UnitRemoveType(u,UNIT_TYPE_GROUND)
     call UnitAddType(u,UNIT_TYPE_PEON)
     call SetUnitPathing(u,false)
     call TimerStart(t,0.03,true,function Jumper)
     set t=null
     set u=null
endfunction

function Jump takes unit u,real angle,real distance,real distanceZ,real time,integer pt returns nothing
     local real X1=GetUnitX(u)
     local real Y1=GetUnitY(u)
     local real Z1=GetZ(X1,Y1)
     local real X2
     local real Y2
     local real Z2
     local real dZ
     local real L
     local integer n=R2I(time/0.03)
     local timer t=CreateTimer()
     local integer id=GetHandleId(t)
     local timer t2=CreateTimer()
     local integer id2=GetHandleId(t2)
     local real Move
     local real MoveX
     local real MoveY
     local real h
     if distance<10. then
       set distance=10.
     endif
     set X2=X1+distance*CosBJ(angle)
     set Y2=Y1+distance*SinBJ(angle)
     set Z2=GetZ(X2,Y2)
     set dZ=(Z1+Z2)/2.
     set L=2.*distance/(1.+SquareRoot(distanceZ/(dZ+distanceZ)))
     set Move=L/I2R(n)
     set MoveX=Move*CosBJ(angle)
     set MoveY=Move*SinBJ(angle)
     set h=distanceZ+dZ
     if GetUnitAbilityLevel(u,'AEev')>0 then
       call DestroyTimer(t)
       call DestroyTimer(t2)
       set t=null
       set t2=null
       return
     endif
     call SaveInteger(udg_h,GetHandleId(u),2,LoadInteger(udg_h,GetHandleId(u),2)+1)
     call SaveUnitHandle(udg_h,id,1,u)
     call SaveReal(udg_h,id,2,L)
     call SaveInteger(udg_h,id,3,0)
     call SaveInteger(udg_h,id,7,n)
     call SaveReal(udg_h,id,4,h)
     call SaveReal(udg_h,id,5,MoveX)
     call SaveReal(udg_h,id,6,MoveY)
     call SaveInteger(udg_h,id,8,pt)
     call CastSpell(u,u,'AHtb',1,OrderId("thunderbolt"))
     call IssueImmediateOrder(u,"stop")
     call SaveUnitHandle(udg_h,id2,1,u)
     call SaveTimerHandle(udg_h,id2,2,t)
     call TimerStart(t2,0.02,false,function JumpContinue)
     set t2=null
     set t=null
endfunction